home *** CD-ROM | disk | FTP | other *** search
/ Chip 2007 January, February, March & April / Chip-Cover-CD-2007-02.iso / Pakiet bezpieczenstwa / mini Pentoo LiveCD 2006.1 / mpentoo-2006.1.iso / livecd.squashfs / usr / share / aclocal-1.5 / multi.m4 < prev    next >
Encoding:
M4 Source File  |  2005-10-16  |  1.4 KB  |  51 lines
  1. # serial 2
  2.  
  3. # AM_ENABLE_MULTILIB([MAKEFILE], [REL-TO-TOP-SRCDIR])
  4. # ---------------------------------------------------
  5. # Add --enable-multilib to configure.
  6. AC_DEFUN([AM_ENABLE_MULTILIB],
  7. [# Default to --enable-multilib
  8. AC_ARG_ENABLE(multilib,
  9. [  --enable-multilib         build many library versions (default)],
  10. [case "$enableval" in
  11.   yes) multilib=yes ;;
  12.   no)  multilib=no ;;
  13.   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
  14.  esac],
  15.               [multilib=yes])
  16.  
  17. # We may get other options which we leave undocumented:
  18. # --with-target-subdir, --with-multisrctop, --with-multisubdir
  19. # See config-ml.in if you want the gory details.
  20.  
  21. if test "$srcdir" = "."; then
  22.   if test "$with_target_subdir" != "."; then
  23.     multi_basedir="$srcdir/$with_multisrctop../$2"
  24.   else
  25.     multi_basedir="$srcdir/$with_multisrctop$2"
  26.   fi
  27. else
  28.   multi_basedir="$srcdir/$2"
  29. fi
  30. AC_SUBST(multi_basedir)
  31.  
  32. AC_OUTPUT_COMMANDS([
  33. # Only add multilib support code if we just rebuilt the top-level
  34. # Makefile.
  35. case " $CONFIG_FILES " in
  36.  *" ifelse([$1],,Makefile,[$1]) "*)
  37.    ac_file=ifelse([$1],,Makefile,[$1]) . ${multi_basedir}/config-ml.in
  38.    ;;
  39. esac],
  40.                    [
  41. srcdir="$srcdir"
  42. host="$host"
  43. target="$target"
  44. with_multisubdir="$with_multisubdir"
  45. with_multisrctop="$with_multisrctop"
  46. with_target_subdir="$with_target_subdir"
  47. ac_configure_args="${multilib_arg} ${ac_configure_args}"
  48. multi_basedir="$multi_basedir"
  49. CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
  50. CC="$CC"])])dnl
  51.